# dns-email.tf
# V1e — SPF + DKIM + DMARC for vauco.no

locals {
  dns_zone = "vaucono"
  domain   = "vauco.no."
}

resource "google_dns_record_set" "spf" {
  name         = local.domain
  managed_zone = local.dns_zone
  type         = "TXT"
  ttl          = 3600
  rrdatas      = ["\"v=spf1 include:_spf.google.com ~all\""]
}

resource "google_dns_record_set" "dkim" {
  name         = "google._domainkey.${local.domain}"
  managed_zone = local.dns_zone
  type         = "TXT"
  ttl          = 3600
  rrdatas = [
    join("", [
      "\"v=DKIM1; k=rsa; p=",
      "MIIBIjANBgkqhkiG9w0BAQEFAAOCAQ8AMIIBCgKCAQEA3BWJTmOMIJ/nNFFOhyKQ",
      "T1Ls35jYaBNKDGErqw2P4hOSpGHzJyMQAl3EkQyWYDC6e/mmk3It3HxwL8mfyyNK",
      "YXUFVVEKadDt58AFiJCNxM+lUAmdg0aM9ePWQ6LNBrkLE3Av7D/zrd40cFkBPP4e",
      "ReKhWQQp94P5BuvoljFM6bTqmdejXuS5fERUMJ2p9aFo7tpSaczI57qt+CYejLaHC",
      "ckgGoYeC7zecLxTQDA6Lfh7wX5rkjyVvU6q/+CeAOdNO+WyWEHPgEFsCnbZ8Lhql",
      "bnrkBib9KmpG99z7Btrnc1SHUj6X0nTfuXfJk+1w0bdlnaTr4asWdP6qVbQnksYSQ",
      "IDAQAB\""
    ])
  ]
}

resource "google_dns_record_set" "dmarc" {
  name         = "_dmarc.${local.domain}"
  managed_zone = local.dns_zone
  type         = "TXT"
  ttl          = 3600
  rrdatas      = ["\"v=DMARC1; p=quarantine; pct=100; rua=mailto:chris.christiansen@vauco.no; ruf=mailto:chris.christiansen@vauco.no; fo=1\""]
}